Web Plotter - Plotting from Incanter to Websites

(ns web-plotter.server
  (:require [compojure.route :as route]
            [compojure.handler :as handler]
            [clojure.string :as str])
  (:use compojure.core
        ring.adapter.jetty
        [ring.middleware.content-type :only (wrap-content-type)]
        [ring.middleware.file :only (wrap-file)]
        [ring.middleware.file-info :only (wrap-file-info)]
        [ring.middleware.stacktrace :only (wrap-stacktrace)]
        [ring.util.response :only (redirect)]
        [hiccup core element page]
        [hiccup.middleware :only (wrap-base-url)]))

(defroutes
  site-routes
  (GET "/" [] (index-page))
  (GET "/scatter" [] (scatter-plot-page))
  (GET "/scatter/data.json" [] (redirect "/data/census-race.json"))
  (route/resources "/")
  (route/not-found "Page not found"))

(def app
  (-> (handler/site site-routes)
    (wrap-file "resources")
    (wrap-file-info)
    (wrap-content-type)))

(ns web-plotter.core)

(deftype Group [key values])

(deftype Point [x y size])

(defn add-label
  [chart axis label]
  (if-not (nil? label)
    (.axisLabel (aget chart axis) label)))

(defn add-axes-labels
  [chart x-label y-label]
  (doto chart
    (add-label "xAxis" x-label)
    (add-label "yAxis" y-label)))

(defn populate-node
  [selector chart groups transition continuation]
  (-> (.select js/d3 selector)
    (.datum groups)
    (.transition)
    (.duration 50000)
    (.call chart)
    (.call continuation)))

(defn create-chart
  [data-url selector make-chart json->groups &
   {:keys [transition continuation x-label y-label]
    :or {transition false continuation (fn [_])
         x-label nil, y-label nil}}]
  (.json js/d3 data-url
    (fn [error data]
      (when data
        (.addGraph js/nv
          (fn [] (let [chart (make-chart)]
                  (add-axes-labels chart x-label y-label)
                  (populate-node selector chart (json->groups data)
                    transition continuation)
                  (.windowResize js/nv.utils #(.update chart)))))))))

(ns web-plotter.scatter
  (:require [web-plotter.core :as web-plotter]))

(defn sum-by [key-fn coll]
  (reduce + 0 (map key-fn coll)))

(defn sum-values [key-fn coll]
  (reduce
    (fn [m [k vs]] (assoc m k (sum-by key-fn vs)))
    {}
    coll))


(defn sum-data-fields [json]
  (let [by-state (group-by #(.-state_name %) json)
        white-by-state (sum-values #(.-white %) by-state)
        afam-by-state (sum-values #(.-black %) by-state)
        total-by-state (sum-values #(.-total %) by-state)]
    (map #(hash-map :state %
            :white (white-by-state %)
            :black (afam-by-state %)
            :total (total-by-state %))
      (keys by-state))))

(defn ->nv [item]
  (let [{:keys [white black]} item]
    (web-plotter/Point. (/ white 1000) (/ black 1000) 1)))

(defn ->nv-data [key-name data]
  (->> data
    sum-data-fields
    (map ->nv)
    (apply array)
    (web-plotter/Group. key-name)
    (array)))

(defn make-chart []
  (let [c (-> (.scatterChart js/nv.models)
            (.showDistX true)
            (.showDistY true)
            (.useVoronoi false)
            (.color (.. js/d3 -scale category10 range)))]
    (.tickFormat (.-xAxis c) (.format js/d3 "d"))
    (.tickFormat (.-yAxis c) (.format js/d3 "d"))
    c))

(defn ^:export scatter-plot []
  (web-plotter/create-chart
    "/scatter/data.json"
    "#scatter svg"
    make-chart
    (partial ->nv-data "Racial Data")
    :x-label "Population, whites, by thousands"
    :y-label "Population, African-Americans, by thousands"
    :transition true))